home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD012a.dsk / TWELVE LABORS.bas < prev   
BASIC Source File  |  2003-06-12  |  20KB  |  473 lines
  1. 100  TEXT : HOME : CLEAR 
  2. 110  REM   PROGRAM LENGTH=11000
  3. 120  REM <CTRL-M><CTRL-M>=================<CTRL-M>PAUL RAYMER<CTRL-M>BOX 42831<CTRL-M>LAS VEGAS NV 89116<CTRL-M>==================<CTRL-J>
  4. 130  HOME 
  5. 140  REM 
  6. 150  REM  PAUL RAYMER'S
  7. 160  REM  MYTHOLOGY
  8. 170  REM  TABLEAUX
  9. 180  REM 
  10. 190  REM  HERCULES
  11. 200  REM  (C)1982 PEC<CTRL-J>
  12. 210  INVERSE : VTAB 3: PRINT "THE TWELVE LABORS OF HERCULES": NORMAL 
  13. 220  VTAB 5: PRINT " 1) THE NEMEAN LION"
  14. 230  PRINT " 2) THE LERNAEAN HYDRA"
  15. 240  PRINT " 3) WILD BOAR OF ERYMANTHUS"
  16. 250  PRINT " 4) THE STYMPHALIAN BIRDS"
  17. 260  PRINT " 5) THE CERYNEIAN HIND"
  18. 270  PRINT " 6) THE STABLES OF AUGEIAS"
  19. 280  PRINT " 7) THE CRETAN BULL"
  20. 290  PRINT " 8) THE MARES OF DIOMEDES"
  21. 300  PRINT " 9) THE GIRDLE OF HIPPOLYTE"
  22. 310  PRINT "10) THE CATTLE OF GERYON"
  23. 320  PRINT "11) GOLDEN APPLES OF THE HESPERIDES"
  24. 330  PRINT "12) JOURNEY TO THE UNDERWORLD"
  25. 335  PRINT "99) ENOUGH OF THIS"
  26. 340  PRINT : HTAB 5: INPUT "SELECT LABOR BY NUMBER ";AN$:AN =  VAL(AN$)
  27. 350  ON AN GOTO 1000,2000,3000,4000,5000,6000,7000,8000,9000,10000,11000,12000
  28. 360  PRINT  CHR$(13); CHR$(4);"RUN MYTHMENU"
  29. 1000  TEXT : HOME 
  30. 1010  REM 
  31. 1020  REM  NEMEAN LION
  32. 1030  REM 
  33. 1040 H$ = "HERCULES"
  34. 1050 L$ = "NEMEAN LION"
  35. 1060  PRINT "#1 - ";H$;" & THE ";L$: FOR Z = 1 TO 2000: NEXT Z
  36. 1070  PRINT H$;" TRIES ARROWS..."
  37. 1080  FOR Z = 1 TO 1000: NEXT Z: HOME 
  38. 1090  FOR Y = 1 TO 3
  39. 1100  FOR X = 13 TO 36
  40. 1110  VTAB 2: HTAB 3: PRINT H$
  41. 1120  VTAB 2: HTAB X: PRINT "-> ";
  42. 1130  FOR Z = 1 TO 50: NEXT Z
  43. 1140  VTAB 2: HTAB X -1: PRINT " ";
  44. 1150  VTAB 2: HTAB 24: PRINT L$
  45. 1160  NEXT X: NEXT Y
  46. 1170  VTAB 1: PRINT "TO NO AVAIL, SO...": FOR Z = 1 TO 1000: NEXT Z: HOME 
  47. 1180  FOR X = 3 TO 24
  48. 1190  VTAB 2: HTAB 24: PRINT L$
  49. 1200  VTAB 2: HTAB X: PRINT H$;"      ";
  50. 1210  VTAB 2: HTAB X -1: PRINT " ";
  51. 1220  FOR Z = 1 TO 50: NEXT Z
  52. 1230  NEXT X
  53. 1240  PRINT : PRINT "DEFEATS THE LION WITH HIS BARE HANDS."
  54. 1250  FOR Z = 1 TO 5000: NEXT Z
  55. 1260  GOTO 130
  56. 2000  TEXT : HOME 
  57. 2010  REM 
  58. 2020  REM  HYDRA
  59. 2030  REM 
  60. 2035 B$ = ""
  61. 2040 H$ = "HERCULES"
  62. 2050  FOR X = 1 TO 5:B$ = B$ + CHR$(8): NEXT X:B$ =  CHR$(10) +B$
  63. 2060 M$ = "-----" +B$ +"(@ @)" +B$ +"  :  " +B$ +"  =  "
  64. 2070  VTAB 22: HTAB 3: PRINT "#2 - THE 9-HEADED HYDRA": FOR Z = 1 TO 2000: NEXT Z
  65. 2080  SPEED= 200
  66. 2090  FOR X = 1 TO 5
  67. 2100  VTAB 1: HTAB X *7: PRINT "HEAD";X
  68. 2110  VTAB 2: HTAB X *7: PRINT M$
  69. 2120  FOR Y = 7 TO 20: VTAB Y: HTAB X *7 +2: PRINT "!";: NEXT Y
  70. 2130  NEXT X
  71. 2140  FOR X = 1 TO 4
  72. 2150  VTAB 8: HTAB (X *7) -4: PRINT "HEAD";X +5
  73. 2160  VTAB 9: HTAB (X *7) -4: PRINT M$
  74. 2170  FOR Y = 13 TO 20: VTAB Y: HTAB (X *7) -2: PRINT "!";: NEXT Y
  75. 2180  NEXT X
  76. 2190  INVERSE 
  77. 2200  FOR X = 20 TO 22: FOR Y = 3 TO 39: VTAB X: HTAB Y: PRINT  CHR$(93);: NEXT Y: NEXT X
  78. 2210  NORMAL 
  79. 2220  FOR X = 3 TO 40  STEP 3: VTAB 23: HTAB X: PRINT "L";: NEXT X
  80. 2230  FOR Z = 1 TO 1000: NEXT Z
  81. 2240  FOR X = 2 TO 29: VTAB 17: HTAB X -1: PRINT " ";: HTAB X: PRINT H$;"->";: NEXT X
  82. 2250  FOR Z = 1 TO 1000: NEXT Z
  83. 2260  FOR X = 16 TO 1  STEP  -1: VTAB X: HTAB 1: CALL  -868: NEXT X
  84. 2270  FOR Z = 1 TO 2000: NEXT Z
  85. 2280  VTAB 17: HTAB 1: PRINT "HYDRA DEFEATED BY HERCULES";
  86. 2290  CALL  -958
  87. 2300  SPEED= 255
  88. 2310  FOR X = 3 TO 40  STEP 3: VTAB 19: HTAB X: PRINT "7";: NEXT X
  89. 2320  FOR Y = 20 TO 22
  90. 2330  INVERSE : FOR X = 3 TO 40: VTAB Y: HTAB X: PRINT "]";: NEXT X: NEXT Y: NORMAL 
  91. 2340  FOR X = 5 TO 39  STEP 4: VTAB 23: HTAB X: PRINT "!";: NEXT X
  92. 2350  FOR Z = 1 TO 5000: NEXT Z
  93. 2360  GOTO 130
  94. 3000  TEXT : HOME 
  95. 3010  REM 
  96. 3020  REM  WILD BOAR
  97. 3030  REM  OF ERYMANTHUS
  98. 3040  REM 
  99. 3050 B$ = "WILD BOAR"
  100. 3060  VTAB 5: HTAB 1: PRINT "#3 - ";B$: FOR Z = 1 TO 2000: NEXT Z: HOME 
  101. 3070  FOR X = 10 TO 30
  102. 3080 R =  INT(7 * RND(1)) +1
  103. 3090  FOR V = 22 TO (22 -R)  STEP  -1
  104. 3100  HTAB X: VTAB V: PRINT "X": NEXT V: NEXT X
  105. 3110  INVERSE : VTAB 23: HTAB 10: PRINT "TERRITORY OF PSOPHIS": NORMAL 
  106. 3120  FOR X = 30 TO 40
  107. 3130  FOR Y = 6 TO 22
  108. 3140  VTAB Y: HTAB X: PRINT "+": NEXT Y: NEXT X
  109. 3150  VTAB 22: HTAB 35: PRINT "MT";
  110. 3160  VTAB 23: HTAB 31: PRINT "ERYMANTHUS";
  111. 3170  FOR X = 31 TO 16  STEP  -1
  112. 3180  FLASH : VTAB 5: HTAB X: CALL  -868: PRINT B$
  113. 3190  GOSUB 3400: NEXT X
  114. 3200  FOR X = 5 TO 21
  115. 3210  VTAB X -1: HTAB 16: PRINT "         ";
  116. 3220  VTAB X: HTAB 16: PRINT B$
  117. 3230  GOSUB 3400: NEXT X
  118. 3240  NORMAL : SPEED= 76
  119. 3250  VTAB 1: HTAB 1: PRINT "AFTER THE WILD BOAR DEVASTATES THE      TERRITORY OF PSOPHIS...HERCULES COMES TOTHE RESCUE AND CAPTURES THE SAVAGE BEAST"
  120. 3260  SPEED= 255
  121. 3270 H$ = " HERCULES"
  122. 3280  FOR X = 1 TO 15: VTAB 21: HTAB X: GOSUB 3400: PRINT H$: NEXT X
  123. 3290 H$ = " HERCULES->WILD BOAR"
  124. 3300  FOR X = 15 TO 20: VTAB 21: HTAB X: PRINT H$: GOSUB 3410: NEXT X
  125. 3310  HOME 
  126. 3320  VTAB 23: HTAB 1: PRINT "TIRYNS"
  127. 3330 H$ = "HERCULES..."
  128. 3340 B$ = "++++++                                  +BOAR+                                  +0==0+ "
  129. 3350  FOR X = 23 TO 1  STEP  -1
  130. 3360  VTAB 20: HTAB X: PRINT H$ +B$
  131. 3370  GOSUB 3410: NEXT X
  132. 3380  FOR Z = 1 TO 5000: NEXT Z
  133. 3390  GOTO 3420
  134. 3400  FOR Z = 1 TO 100: NEXT Z: RETURN 
  135. 3410  FOR Z = 1 TO 1000: NEXT Z: RETURN 
  136. 3420  GOTO 130
  137. 4000  TEXT : HOME 
  138. 4010  REM 
  139. 4020  REM  STYMPHALIAN BIRDS
  140. 4030  REM 
  141. 4040  VTAB 3: PRINT "#4 - THE IRON-WINGED STYMPHALIAN BIRDS": FOR Z = 1 TO 2000: NEXT Z: HOME 
  142. 4050 B$ = "FE=BIRD=FE                                  FE     "
  143. 4060  FOR A = 1 TO 30
  144. 4070 X =  INT(30 * RND(1)) +1
  145. 4080 Y =  INT(20 * RND(1)) +1
  146. 4090  VTAB Y: HTAB X: PRINT B$
  147. 4100  FOR Z = 1 TO 500: NEXT Z
  148. 4110  NEXT A
  149. 4120  SPEED= 76: INVERSE : VTAB 1: HTAB 1: PRINT "  HERCULES FRIGHTENS THE BIRDS WITH       CYMBALS AND SLAYS THEM WITH ARROWS... ": FOR Z = 1 TO 2000: NEXT Z: SPEED= 200: NORMAL 
  150. 4130 S$ = "ACALAMSBARASATBABKBEBI BBRCDCACF CCECSCLCRCOCUCMDYESEREUFM FFRGDGAGEAUHFHAHEHO HIN IIRFEKRLALRPBLILUMGMNMDHGMONDNENPNINB NNOOS OPD PPTPUPO KPRPMPAULRARNRERHRBRURFSMSCSESIAGNASR STATCTETBTLTHTMSNTI W U VXEYB YZNZR"
  151. 4140  VTAB 1: HTAB 1
  152. 4150  FOR X = 1 TO  LEN(S$)  STEP 2
  153. 4160 W$ =  MID$ (S$,X,2)
  154. 4170  PRINT W$; SPC( 6);
  155. 4180  NEXT X
  156. 4190  SPEED= 255
  157. 4200  FOR X = 1024 TO 2039  STEP 4
  158. 4210  POKE X,173: POKE X +1,190
  159. 4220  FOR Z = 1 TO 50: NEXT Z
  160. 4230  NEXT X
  161. 4240  FOR Z = 1 TO 5000: NEXT Z
  162. 4250  GOTO 130
  163. 5000  TEXT : HOME 
  164. 5010  REM 
  165. 5020  REM  THE CERYNEIAN HIND
  166. 5030  REM 
  167. 5040  PRINT "#5 - SEARCH FOR THE GOLDEN HORNED HIND": FOR Z = 1 TO 2000: NEXT Z
  168. 5050  HOME 
  169. 5060  FOR X = 1 TO 52
  170. 5070  VTAB 1: HTAB 1: PRINT "WEEK NO.";X
  171. 5080 R =  INT(30 * RND(1)) +1
  172. 5090 RR =  INT(22 * RND(1)) +1
  173. 5100  FLASH : VTAB RR: HTAB R: PRINT "HIND": NORMAL 
  174. 5110  FOR Z = 1 TO 200: NEXT Z
  175. 5120  VTAB RR: HTAB R: PRINT "    "
  176. 5130  FOR Z = 1 TO 50: NEXT Z
  177. 5140  VTAB RR: HTAB R: PRINT "HERCULES"
  178. 5150  FOR Z = 1 TO 150: NEXT Z
  179. 5160  VTAB RR: HTAB R: PRINT "        "
  180. 5170  NEXT X
  181. 5180  VTAB 23: HTAB 36: FLASH : PRINT "HIND": NORMAL 
  182. 5190  FOR X = 5 TO 34: VTAB 23: HTAB X: PRINT " ...H": FOR Z = 1 TO 200: NEXT Z: NEXT X
  183. 5200  FOR X = 34 TO 1  STEP  -1: VTAB 23: HTAB X: PRINT "H...14K ";: FOR Z = 1 TO 50: NEXT Z: NEXT X
  184. 5210  FOR Z = 1 TO 5000: NEXT Z
  185. 5220  GOTO 130
  186. 6000  TEXT : HOME 
  187. 6010  REM 
  188. 6020 ST$ = "STABLES OF AUGEIAS"
  189. 6030  REM 
  190. 6035 B$ = ""
  191. 6040  FOR I = 1 TO 5:B$ = B$ + CHR$(8): NEXT I
  192. 6050  PRINT "#6 - ";ST$: FOR Z = 1 TO 2000: NEXT Z: HOME 
  193. 6060 C$ = "    V" + CHR$(10) +B$ +",===@" + CHR$(10) +B$ +" L L "
  194. 6070  FOR X = 3 TO 36  STEP 6: FOR Y = 1 TO 22  STEP 5: VTAB Y: HTAB X: PRINT C$;: FOR Z = 1 TO 50: NEXT Z: NEXT Y: NEXT X
  195. 6080  FOR Z = 1 TO 2000: NEXT Z
  196. 6090  SPEED= 200: PRINT : FOR X = 1 TO 760: PRINT "*";: NEXT X: SPEED= 255
  197. 6100  FOR Z = 1 TO 500: NEXT Z
  198. 6110  VTAB 10: HTAB 22: PRINT " AUGEIAS: "; CHR$(34);"HELP!"; CHR$(34) CHR$(32)
  199. 6120 M$ = " HERCULES TO THE RESCUE................"
  200. 6130  SPEED= 181
  201. 6140  FOR X =  LEN(M$) TO 1  STEP  -1
  202. 6150  VTAB 23: HTAB X: PRINT  MID$ (M$,X,X)
  203. 6160  NEXT X: SPEED= 255
  204. 6170  VTAB 1: HTAB 1: INVERSE : PRINT "ALPHEUS                         PENEIUS ";: PRINT "RIVER                             RIVER ";
  205. 6180  FOR Z = 1 TO 1000: NEXT Z
  206. 6190  FOR X = 3 TO 23: VTAB X: HTAB 1: PRINT "  ": VTAB X: HTAB 39: PRINT "  ";: FOR Z = 1 TO 50: NEXT Z: NEXT X
  207. 6200  FOR X = 23 TO 1  STEP  -1
  208. 6210  FOR Y = 1 TO 40
  209. 6220  VTAB X: HTAB Y: PRINT " ": NEXT Y: FOR Z = 1 TO 50: NEXT Z: NEXT X
  210. 6230  NORMAL 
  211. 6240  FOR X = 1 TO 17: FOR Y = 1 TO 40: VTAB X: HTAB Y: PRINT " ": NEXT Y: NEXT X
  212. 6250  FOR X = 3 TO 36  STEP 6: VTAB 20: HTAB X: PRINT C$: NEXT X
  213. 6260  VTAB 17: HTAB 11: FLASH : PRINT ST$: NORMAL 
  214. 6270  FOR Z = 1 TO 5000: NEXT Z
  215. 6280  GOTO 130
  216. 7000  TEXT : HOME 
  217. 7010  REM 
  218. 7020  REM  CRETAN BULL
  219. 7030  REM 
  220. 7035 B$ = ""
  221. 7040  FOR I = 1 TO 3:B$ = B$ + CHR$(8): NEXT I
  222. 7050  REM 
  223. 7060  VTAB 10: PRINT "#7 - THE CRETAN BULL": FOR Z = 1 TO 2000: NEXT Z: HOME 
  224. 7070  VTAB 10: HTAB 1: PRINT "ARGOLIS": VTAB 10: HTAB 33: INVERSE : PRINT "CRETE": NORMAL 
  225. 7080 T$ = "( )" + CHR$(10) +B$ +"0 0" + CHR$(10) +B$ +" # " + CHR$(10) +B$ +" ^ "
  226. 7090  VTAB 17: HTAB 26: PRINT T$
  227. 7100  FOR X = 29 TO 39
  228. 7110  FOR Y = 19 TO 21
  229. 7120  VTAB Y: HTAB X: PRINT "#": NEXT Y: NEXT X
  230. 7130  FOR X = 22 TO 23
  231. 7140  VTAB X: HTAB 30: PRINT "I        I"
  232. 7150  NEXT X
  233. 7160  FOR Z = 1 TO 1000: NEXT Z
  234. 7170  FOR X = 1 TO 25: VTAB 17: HTAB X: PRINT "-";: FOR Z = 1 TO 50: NEXT Z: NEXT X
  235. 7180  FOR X = 26 TO 1  STEP  -1
  236. 7190  VTAB 17: HTAB X: PRINT T$: FOR Z = 1 TO 50: NEXT Z
  237. 7200  VTAB 17: HTAB X +3: PRINT "  "
  238. 7210  VTAB 18: HTAB X +3: PRINT "  ": VTAB 19: HTAB X +3: PRINT "#"
  239. 7220  VTAB 20: HTAB X +3: PRINT "#": VTAB 21: HTAB X +3: PRINT "#"
  240. 7230  IF X/8 =  INT(X/8)  THEN  VTAB 22: HTAB X -3: PRINT "I": VTAB 23: HTAB X -3: PRINT "I"
  241. 7240  FOR Z = 1 TO 50: NEXT Z
  242. 7250  NEXT X
  243. 7260  FOR X = 40 TO 15  STEP  -1
  244. 7270  FOR Y = 17 TO 23: VTAB Y: HTAB X: PRINT " ": NEXT Y: FOR Z = 1 TO 50: NEXT Z: NEXT X
  245. 7280  FLASH : VTAB 19: HTAB 15: PRINT "*"
  246. 7290  VTAB 9: HTAB 1: PRINT "ARGOLIS": NORMAL : VTAB 9: HTAB 33: PRINT "CRETE"
  247. 7300  FOR Z = 1 TO 5000: NEXT Z
  248. 7310  GOTO 130
  249. 8000  TEXT : HOME 
  250. 8010  REM 
  251. 8020  REM  MARES OF DIOMEDES
  252. 8030  REM 
  253. 8040  VTAB 3: PRINT "#8 - MARES OF DIOMEDES": FOR Z = 1 TO 2000: NEXT Z: HOME 
  254. 8050 HP = 47
  255. 8060  FOR H = 0 TO 30  STEP 10
  256. 8070  FOR X = 3 +H TO 9 +H: VTAB 2: HTAB X: PRINT  CHR$(HP): NEXT X
  257. 8080  INVERSE 
  258. 8090  FOR X = 3 +H TO 9 +H: FOR Y = 3 TO 11: VTAB Y: HTAB X: PRINT " ": NEXT Y: NEXT X: NORMAL 
  259. 8100  VTAB 5: HTAB 4 +H: PRINT "O";: VTAB 5: HTAB 8 +H: PRINT "O";
  260. 8110  VTAB 5: HTAB 2 +H: PRINT "<";: VTAB 5: HTAB 10 +H: PRINT ">"
  261. 8120  VTAB 6: HTAB 6 +H: PRINT  CHR$(34);
  262. 8130  VTAB 8: HTAB 4 +H: PRINT "VVVVV";
  263. 8140 T$ = "^^^^^"
  264. 8150  FOR X = 1 TO 10
  265. 8160  VTAB 9: HTAB 4 +H: PRINT  SPC( 5);
  266. 8170  VTAB 10: HTAB 4 +H: PRINT T$;
  267. 8180  FOR Z = 1 TO 150: NEXT Z
  268. 8190  VTAB 10: HTAB 4 +H: INVERSE : PRINT  SPC( 5): NORMAL 
  269. 8200  FOR Z = 1 TO 300
  270. 8210  VTAB 9: HTAB 4 +H: PRINT T$;
  271. 8220  FOR Z = 1 TO 150: NEXT Z
  272. 8230  VTAB 10: HTAB 4 +H: INVERSE : PRINT  SPC( 5): NORMAL 
  273. 8240  NEXT X
  274. 8250  IF H = 0  THEN  VTAB 14: HTAB 2 +H: PRINT "     THE"
  275. 8260  IF H = 10  THEN  VTAB 14: HTAB 2 +H: PRINT "TERRIBLE"
  276. 8270  IF H = 20  THEN  VTAB 14: HTAB 2 +H: PRINT "MARES OF"
  277. 8280  IF H = 30  THEN  VTAB 14: HTAB 2 +H: PRINT "DIOMEDES"
  278. 8290 HP = HP -2
  279. 8300  NEXT H
  280. 8310  FOR Z = 1 TO 1000: NEXT Z
  281. 8320 H$ = "HERE COMES HERCULES!!!!!!!!!!!!!!!!!": SPEED= 100
  282. 8330  FOR X = 40 TO 1  STEP  -1
  283. 8340  VTAB 20: HTAB X: PRINT  MID$ (H$,X,1)
  284. 8350  NEXT X: SPEED= 255
  285. 8360  FOR H = 0 TO 30  STEP 10
  286. 8370  VTAB 5: HTAB 4 +H: PRINT "X";: VTAB 5: HTAB 8 +H: PRINT "X";
  287. 8380  VTAB 8: HTAB 4 +H: PRINT "     ";
  288. 8390 R =  INT(4 * RND(1)) +1:RR =  INT(4 * RND(1)) +1: IF RR = R  THEN 8390
  289. 8400  VTAB 8: HTAB 4 +H +R: PRINT "U";
  290. 8410  VTAB 8: HTAB 4 +H +RR: PRINT "'";
  291. 8420  VTAB 9: HTAB 4 +H: PRINT "     ";
  292. 8430 R =  INT(4 * RND(1)) +1
  293. 8440  VTAB 9: HTAB 4 +H +R: PRINT "^";
  294. 8450  FOR Z = 1 TO 500: NEXT Z
  295. 8460  NEXT H
  296. 8470  VTAB 14: HTAB 1: PRINT "THE NOT SO";
  297. 8480  FOR Z = 1 TO 1000: NEXT Z
  298. 8490  VTAB 20: HTAB 1: PRINT "GOOD WORK,"
  299. 8500  FOR Z = 1 TO 5000: NEXT Z
  300. 8510  GOTO 130
  301. 9000  TEXT : HOME 
  302. 9010  REM 
  303. 9020  REM  GIRDLE OF HIPPOLYTE
  304. 9030  REM 
  305. 9040  VTAB 22: HTAB 1: PRINT "#9 - THE GIRDLE OF HIPPOLYTE": FOR Z = 1 TO 2000: NEXT Z: HOME 
  306. 9050 A$ = "O" + CHR$(10) + CHR$(8) +"+"
  307. 9060 S$ =  CHR$(32)
  308. 9070 Z$ = "+" + CHR$(10) + CHR$(8) +"0"
  309. 9080 H$ = "^ " + CHR$(10) + CHR$(8) + CHR$(8) +"! " + CHR$(10) + CHR$(8) + CHR$(8) +"O "
  310. 9090  INVERSE : FOR X = 1 TO 40: VTAB 1: HTAB X: PRINT S$;: VTAB 23: HTAB X: PRINT S$;: NEXT X
  311. 9100  FOR Y = 1 TO 23: VTAB Y: HTAB 1: PRINT S$;: VTAB Y: HTAB 40: PRINT S$;: NEXT Y: NORMAL 
  312. 9110  VTAB 3: HTAB 5: PRINT "THE AMAZON KINGDOM OF HIPPOLYTE";
  313. 9120  FOR X = 3 TO 37  STEP 2
  314. 9130  FOR Y = 5 TO 20  STEP 3
  315. 9140  VTAB Y: HTAB X: PRINT A$
  316. 9150  NEXT Y: NEXT X
  317. 9160 R =  INT(18 * RND(1)) +1
  318. 9170 RR =  INT(6 * RND(1)) +1
  319. 9180  VTAB (RR *3) +1: HTAB (R *2) +1: FLASH : PRINT "W";: NORMAL 
  320. 9190  FOR Z = 1 TO 1000: NEXT Z
  321. 9200 L =  INT(18 * RND(1)) +1
  322. 9210 LL =  INT(6 * RND(1)) +1
  323. 9220  IF L = R  AND LL = RR  THEN  GOSUB 9270: VTAB (LL *3) +1: HTAB (L *2) +1: PRINT H$: FOR X = (L *2) +1 TO 2  STEP  -1: VTAB (LL *3) +1: HTAB X: PRINT H$;: FOR Z = 1 TO 250: NEXT Z: NEXT X: GOTO 9280
  324. 9230  FOR Z = 1 TO 100: NEXT Z: VTAB (LL *3) +2: HTAB (L *2) +1: PRINT Z$;
  325. 9240  INVERSE : VTAB 3: HTAB 4: PRINT " AFTER HERCULES KILLS THE AMAZONS";: NORMAL 
  326. 9250  GOTO 9200
  327. 9260  GOTO 9280
  328. 9270  FLASH : VTAB 3: HTAB 3: PRINT " HERCULES TAKES THE QUEEN'S GIRDLE ";: NORMAL : FOR Z = 1 TO 2000: NEXT Z: RETURN 
  329. 9280  FOR Z = 1 TO 5000: NEXT Z
  330. 9290  GOTO 130
  331. 10000  TEXT : HOME 
  332. 10010  REM 
  333. 10020  REM  CATTLE OF GERYON
  334. 10030  REM 
  335. 10035 OX$ = "":H = 0
  336. 10040 R =  INT(14 * RND(1)) +1:B = R +32
  337. 10050  VTAB 5: PRINT "#10 - THE CATTLE OF GERYON": FOR Z = 1 TO 2000: NEXT Z: HOME 
  338. 10060  INVERSE 
  339. 10070  FOR X = 17 TO 23: FOR Y = 2 TO 6: HTAB X: VTAB Y: PRINT " ": NEXT Y: NEXT X: NORMAL 
  340. 10080  FLASH : VTAB 3: HTAB 18: PRINT " ";: VTAB 3: HTAB 22: PRINT " ";: NORMAL : VTAB 5: HTAB 18: PRINT "XXXXX";
  341. 10090  VTAB 7: HTAB 20: PRINT "="
  342. 10100  FOR X = 9 TO 33: VTAB 8: HTAB X: PRINT "=": NEXT X
  343. 10110  FOR I = 1 TO 3
  344. 10120  FOR X = 4 +H TO 14 +H
  345. 10130  FOR Y = 9 TO 15
  346. 10140  VTAB Y: HTAB X: PRINT  CHR$(B)
  347. 10150  NEXT Y
  348. 10160  NEXT X
  349. 10170  FOR Q = 16 TO 18
  350. 10180  VTAB Q: HTAB 7 +H: PRINT  CHR$(B +32): VTAB Q: HTAB 11 +H: PRINT  CHR$(B +32)
  351. 10190  IF Q = 18  THEN  VTAB Q: HTAB 6 +H: PRINT  CHR$(B +32): VTAB Q: HTAB 8 +H: PRINT  CHR$(B +32): VTAB Q: HTAB 10 +H: PRINT  CHR$(B +32): VTAB Q: HTAB 12 +H: PRINT  CHR$(B +32)
  352. 10200  NEXT Q
  353. 10210 H = H +12:B = B +1
  354. 10220  NEXT I
  355. 10230 A$ = "THE THREE-BODIED MONSTER WATCHES HIS"
  356. 10240 B$ = "HERD OF RED OXEN ON THE COAST OF IBERIA"
  357. 10250 C$ = "......................................."
  358. 10260 D$ = "HERCULES TAKES POSSESSION OF THE OXEN.."
  359. 10270  FOR A = 1 TO 4
  360. 10280  FOR X = 1 TO  LEN(A$)
  361. 10290  VTAB 21: HTAB X: PRINT  MID$ (A$,X,1)
  362. 10300  FOR Z = 1 TO 100: NEXT Z
  363. 10310  NEXT X
  364. 10320  IF A = 1  THEN A$ = B$
  365. 10330  IF A = 2  THEN A$ = C$
  366. 10340  IF A = 3  THEN A$ = D$
  367. 10350  IF A = 4  THEN A$ = C$
  368. 10360  NEXT A
  369. 10370  FOR X = 1 TO 20: PRINT  CHR$(10): NEXT X
  370. 10380  FOR X = 1 TO 70:OX$ = OX$ +"=OX": NEXT X
  371. 10390 O$ = "               HERCULES..." +OX$ +"."
  372. 10400  FOR X = 1 TO  LEN(O$)
  373. 10410  VTAB 23: HTAB 1: PRINT  MID$ (O$,X,39);: FOR Z = 1 TO 50: NEXT Z: NEXT X
  374. 10420  FOR Z = 1 TO 5000: NEXT Z
  375. 10430  GOTO 130
  376. 11000  TEXT : HOME 
  377. 11010  REM 
  378. 11020  REM  GOLDEN APPLES OF
  379. 11030  REM  THE HESPERIDES
  380. 11040  REM 
  381. 11050  FOR X = 11 TO 36  STEP 5
  382. 11060  VTAB 20: HTAB X: PRINT  CHR$(93) CHR$(32) CHR$(91): NEXT X
  383. 11070  FOR X = 21 TO 22
  384. 11080  FOR Y = 12 TO 37  STEP 5: VTAB X: HTAB Y: PRINT "I": NEXT Y: NEXT X
  385. 11090  FOR X = 10 TO 39: VTAB 23: HTAB X: PRINT "^": NEXT X
  386. 11100  VTAB 15: HTAB 19: PRINT "THE GOLDEN APPLES": VTAB 16: HTAB 19: PRINT "OF THE HESPERIDES"
  387. 11110  FOR Z = 1 TO 2000: NEXT Z
  388. 11120  VTAB 1: HTAB 2: PRINT "%%%%%%%"
  389. 11130  VTAB 2: HTAB 2: PRINT "======="
  390. 11140  VTAB 3: HTAB 3: PRINT " O O"
  391. 11150  VTAB 4: HTAB 1: PRINT "))  =  (("
  392. 11160  VTAB 6: HTAB 3: PRINT " ^^^"
  393. 11170  VTAB 7: HTAB 3: PRINT "  H"
  394. 11180  VTAB 6: HTAB 17: PRINT "<- WATCHED OVER BY": VTAB 7: HTAB 20: PRINT "THE DRAGON": VTAB 8: HTAB 20: PRINT "LADON!"
  395. 11190  FOR I = 1 TO 13
  396. 11200  FOR X = 8 TO 20
  397. 11210 R =  INT(10 * RND(1)) +1
  398. 11220 C =  INT((10 -R)/2)
  399. 11230  VTAB X: HTAB 1: PRINT  SPC( 10);
  400. 11240  VTAB X: HTAB C +1: FOR L = 1 TO R: PRINT "*";
  401. 11250  NEXT L: PRINT 
  402. 11260  NEXT X
  403. 11270  VTAB 3: HTAB 3: PRINT " O O"
  404. 11280  IF I/3 =  INT(I/3)  THEN  VTAB 3: HTAB 3: PRINT " 0 0"
  405. 11290  IF I/2 =  INT(I/2)  THEN  VTAB 3: HTAB 3: PRINT " Q Q"
  406. 11300 F$ = "X"
  407. 11310  IF I >4  THEN F$ = "$"
  408. 11320  IF I >8  THEN F$ = "+"
  409. 11330  FOR F = 21 TO 23: VTAB F: HTAB 4: PRINT F$;: VTAB F: HTAB 6: PRINT F$;: NEXT F
  410. 11340  VTAB 23: HTAB 2: PRINT F$;F$;: VTAB 23: HTAB 7: PRINT F$;F$;
  411. 11350  FOR Z = 1 TO 200: NEXT Z: NEXT I
  412. 11360  VTAB 6: HTAB 17: PRINT "HERCULES KILLS    "
  413. 11370  POKE 33,10
  414. 11380  VTAB 1: HTAB 1
  415. 11390  FOR X = 1 TO 240: PRINT " ";: FOR Z = 1 TO (240 -2 *X): NEXT Z: NEXT X
  416. 11400  POKE 33,40
  417. 11410  VTAB 14: HTAB 19: PRINT "TAKES THE"
  418. 11420  VTAB 17: HTAB 19: PRINT "AND LEAVES ONLY"
  419. 11430 R =  INT(3 * RND(1)) +1
  420. 11440  ON R GOTO 11460,11470,11480
  421. 11450  REM  FOR X = 11 TO 36 STEP 5
  422. 11460  FOR X = 11 TO 36  STEP 5: VTAB 20: HTAB X: PRINT  CHR$(84) CHR$(82) CHR$(83): NEXT X: POKE 1138,84: POKE 1139,82: POKE 1140,83: GOTO 11490
  423. 11470  FOR X = 11 TO 36  STEP 5: VTAB 20: HTAB X: PRINT  CHR$(73) CHR$(66) CHR$(77): NEXT X: POKE 1138,73: POKE 1139,66: POKE 1140,77: GOTO 11490
  424. 11480  FOR X = 11 TO 36  STEP 5: VTAB 20: HTAB X: PRINT  CHR$(80) CHR$(69) CHR$(84): NEXT X: POKE 1138,80: POKE 1139,69: POKE 1140,84: GOTO 11490
  425. 11490  FOR Z = 1 TO 5000: NEXT Z
  426. 11500  GOTO 130
  427. 12000  TEXT : HOME 
  428. 12010  REM 
  429. 12020  REM  JOURNEY TO UNDERWORLD
  430. 12030  REM 
  431. 12040  VTAB 23: HTAB 1: PRINT "JOURNEY TO THE UNDERWORLD": FOR Z = 1 TO 2000: NEXT Z: HOME 
  432. 12050 S$ =  CHR$(32)
  433. 12060  INVERSE 
  434. 12070  FOR X = 1 TO 16: VTAB 16: HTAB X: PRINT S$;: NEXT X
  435. 12080  FOR Y = 17 TO 23: FOR X = 1 TO 2: VTAB Y: HTAB X: PRINT S$;: NEXT X: NEXT Y
  436. 12090  FOR X = 1 TO 39: VTAB 24: HTAB X: PRINT S$;: NEXT X
  437. 12100  FOR X = 23 TO 39: FOR Y = 16 TO 17: VTAB Y: HTAB X: PRINT S$;: NEXT Y: NEXT X
  438. 12110  FOR X = 36 TO 39: FOR Y = 18 TO 21: VTAB Y: HTAB X: PRINT S$;: NEXT Y: NEXT X
  439. 12120  FOR X = 13 TO 16: FOR Y = 17 TO 20: VTAB Y: HTAB X: PRINT S$;: NEXT Y: NEXT X
  440. 12130  FOR X = 23 TO 39: FOR Y = 22 TO 23: VTAB Y: HTAB X: PRINT S$;: NEXT Y: NEXT X
  441. 12140  FOR X = 23 TO 27: FOR Y = 18 TO 19: VTAB Y: HTAB X: PRINT S$;: NEXT Y: NEXT X
  442. 12150  VTAB 19: HTAB 29: PRINT "HADE'S"
  443. 12160  VTAB 20: HTAB 30: PRINT "HOME"
  444. 12170  FLASH : FOR X = 3 TO 22: VTAB 23: HTAB X: PRINT "^": NEXT X: INVERSE 
  445. 12180  FOR X = 23 TO 39
  446. 12190 R =  INT(15 * RND(1)) +1
  447. 12200  FOR Y = 15 TO R  STEP  -1
  448. 12210  VTAB Y: HTAB X: PRINT S$;: NEXT Y: NEXT X: NORMAL 
  449. 12220  SPEED= 100
  450. 12230  VTAB 21: HTAB 4: PRINT "UNDERWORLD";
  451. 12240  VTAB 3: HTAB 17: PRINT "HERCULES";: VTAB 4: HTAB 17: PRINT "BATTLES";
  452. 12250  VTAB 5: HTAB 17: PRINT "WITH";: VTAB 6: HTAB 17: PRINT "CEREBUS,";
  453. 12260  VTAB 7: HTAB 17: PRINT "GUARDIAN";: VTAB 8: HTAB 17: PRINT "OF THE";
  454. 12270  VTAB 9: HTAB 17: PRINT "GATES...";
  455. 12280  SPEED= 255
  456. 12290  FOR Z = 1 TO 2000: NEXT Z
  457. 12300  VTAB 15: HTAB 17: PRINT "CERBERUS";
  458. 12310  FOR X = 2 TO 22: VTAB X: HTAB 17: PRINT "HERCULES";
  459. 12320  VTAB X -1: HTAB 17: PRINT "        ";
  460. 12330  IF X = 16  THEN  FLASH 
  461. 12340  IF X >16  THEN  VTAB X +1: HTAB 17: PRINT "CERBERUS";
  462. 12350  FOR Z = 1 TO 50: NEXT Z: NEXT X
  463. 12360  NORMAL 
  464. 12370  FOR Z = 1 TO 1000: NEXT Z
  465. 12380  FOR X = 22 TO 15  STEP  -1
  466. 12390  VTAB X +1: HTAB 17: PRINT "        
  467. 12400  VTAB X: HTAB 17: PRINT "HERCULES";
  468. 12410  FOR Z = 1 TO 150: NEXT Z
  469. 12420  NEXT X
  470. 12430  FOR X = 18 TO 1  STEP  -1
  471. 12440  VTAB 15: HTAB X: PRINT "H-3D0G ";: FOR Z = 1 TO 100: NEXT Z: NEXT X
  472. 12450  FOR Z = 1 TO 5000: NEXT Z
  473. 12460  GOTO 130